【Excel】数据清洗|一键提取括号/逗号内指定内容,1秒搞定几百条数据!
- 2026-11-07 22:47:35
做报表、整理信息时最崩溃的就是：
一长串文字里，只想要括号里的内容，或者逗号前面/后面的内容；
比如：
提取括号内的内容：产品名称(规格)→规格
提取逗号前/后的内容：XX省，XX市，XX区→城市
提取指定分隔符之间的内容：2026-3-15→3
提取指定分隔符后的内容：姓名：张三→张三
几百条数据手动复制粘贴，至少半小时，还容易错。
今天格子间教你：3个方法，轻松提取括号内、逗号后、任意分隔符中的指定内容！
复制粘贴公式就能用，职场人必学！
方法1：智能填充法（无公式）
①在【提取】列，手动输入想要提取的内容；
②同时选中手动输入的内容+所有需要提取的单元格，按【Ctrl+E】智能填充；
③或者双击填充柄，在填充选项中，选择【快速填充】。
方法2：函数公式法（更灵活）
场景1：提取【括号】内的内容
核心公式：
=MID(A2,FIND("（",A2)+1,FIND("）",A2)-FIND("（",A2)-1)
注意：括号需要区分中英文状态，否则会报错。
优化公式：
=IFERROR(MID(A3,FIND("（",A3)+1,FIND("）",A3)-FIND("（",A3)-1),"无匹配项")
场景2：提取【逗号】前/后的内容
①提取逗号前
核心公式：
=LEFT(A2,FIND("，",A2)-1)
注意：逗号需要区分中英文状态，否则会报错。
优化公式：
=IFERROR(LEFT(A7,FIND("，",A7)-1),"无匹配项")
②提取逗号后
核心公式：
=RIGHT(A2,LEN(A2)-FIND("，",A2))
优化公式：
=IFERROR(RIGHT(A7,FIND("，",A7)-1),"无匹配项")
③提取第N个逗号后
核心公式1（全版本通用）：
=MID(A2,FIND("@",SUBSTITUTE(A2,"，","@",N))+1,LEN(A2))
优化公式1（全版本通用）：
=IFERROR(MID(A5,FIND("@",SUBSTITUTE(A5,"，","@",N))+1, LEN(A5)), "无匹配项")
备注：
N表示提取的第N个逗号，后同；
@标记作用，可以替换成其他不常用的符号，后同。
注意：符号区分中英文，后同。
核心公式2(Microsoft 365/ Excel 2024)：
=TEXTAFTER(A2,"，",N)
优化公式2(Microsoft 365/ Excel 2024)：
=IFERROR(TEXTAFTER(A5,"，",N),"无匹配项")
④提取第N个逗号前
核心公式1（全版本通用）：
=LEFT(A2,FIND("@",SUBSTITUTE(A2,"，","@",N))-1)
优化公式1（全版本通用）：
=IFERROR(LEFT(A5,FIND("@",SUBSTITUTE(A5,"，","@",N))-1),"无匹配项")
核心公式2(Microsoft 365/ Excel 2024)：
=TEXTBEFORE(A2,"，",N)
优化公式2(Microsoft 365/ Excel 2024)：
=IFERROR(TEXTBEFORE(A5,"，",N),"无匹配项")
⑤提取第M个逗号和第N个逗号之间的内容
优化公式1（全版本通用）：
=IFERROR(MID(A2,FIND("@",SUBSTITUTE(A2,"，","@",M))+1,FIND("@",SUBSTITUTE(A2,"，","@",N))-FIND("@",SUBSTITUTE(A2,"，","@",M))-1),"无匹配项")
优化公式2(Microsoft 365/ Excel 2024)：
=IFERROR(INDEX(TEXTSPLIT(A2,"，"),N),"无匹配项")
注意：公式2与公式1有差异
公式1的M和N均需保证单元格存在对应位置的符号，否则报错；
公式2表示先按照特定符号切割，然后再取对应位置上的数据。
方法3：数据分列法（量大优势）
操作步骤：
①复制原数据列备份，在备份数据上进行操作；
②依次点击【数据-分列】；
③选择分类依据【分隔符号】或【固定宽度】；
④若选择【分隔符号】下一步需要确定具体分隔符号（区分中英文），若选择【固定宽度】下一步需要确认具体宽度；
⑤后面继续选择【下一步-完成】即可。
避坑指南
①符号一定要区分中英文！
②公式最好【IFERROR】包裹，避免报错！
③数据备份好习惯，方便回溯！
💬评论区说说：
你平时最常提取什么内容？
括号？逗号？还是空格前后？
👇关注格子，学习更多办公实用技巧，2026争取少加班、早下班！
